200行AS代码的贪食蛇

0点看完春晚,表示太兴奋,睡不着。于是就想找点事情做嘛。于是顺手就打开了flash ide,想着,其实自己进入游戏行业的时候,根本就不是从简入深的做,一开始就做联机游戏demo了(虽然很失败)。貌似简单的贪食蛇啊,俄罗斯方块的都没做过。 还觉得自己可能连贪食蛇都写不出来呢(笑)

于是写着写着就写出来了 =。= ,写了半个小时就写完了。 于是果断加点注释,做个教程好了。

【鼠标点击一下网格,之后只要移动方向键吃食物就好啦。(可穿墙,自己碰到自己游戏失败)】

以下代码只要打开flash ide 创建一个as3 的fla文件,复制到第一帧上就能用啦。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
import flash.display.Sprite;
import flash.events.KeyboardEvent;
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.geom.Point;
import flash.text.TextField;


var peace:int = 10;//区块大小(地图网格,蛇身,食物)
var player:Sprite; // 蛇头
var playerPoint:Array = []; // 蛇头坐标
var snake:Array = []; //蛇身数组
var direction:String; //初始化移动方向
var bg:Sprite; //背景网格
var timer:Timer = new Timer(100); //游戏render
var seed:Timer = new Timer(2000); //食物创建计时器
var square:Sprite; //食物,蛇 容器
var foods:int; //食物
var score:int; //分数

init();

function init():void //游戏初始化
{
    bg=new Sprite();
    square=new Sprite();
    player=new Sprite();
    direction="right";
    score=0;
    foods=0;
   
    for (var i:int=0; i<30; i++) //绘制30*30的网格
    {
        for (var j:int=0; j<30; j++)
        {
            bg.graphics.lineStyle(1,0x000000);
            bg.graphics.drawRect(i*peace,j*peace,peace,peace);
            bg.graphics.endFill();
        }
    }

    addChild(square);
    addChild(bg);

    player=makeBody(0x00ffff);//绘制蛇头
    square.addChild(player);
    snake[0] = player;

    for (var len:int=0; len<1; len++)//创建初始蛇身
    {
        var body = makeBody();
        square.addChild(body);
        snake.push(body);
    }
   
    timer.start();
    timer.addEventListener(TimerEvent.TIMER,onTimer);
    seed.start();
    seed.addEventListener(TimerEvent.TIMER,onSeed);
    stage.addEventListener(KeyboardEvent.KEY_DOWN,keyDown);
}

function gameOver():void //游戏结束
{
    timer.stop();
    timer.removeEventListener(TimerEvent.TIMER,onTimer);
    seed.stop();
    seed.removeEventListener(TimerEvent.TIMER,onSeed);
    snake=[];
    playerPoint=[];
    removeChild(bg);
    bg=null;
    removeChild(square);
    square=null;
    var tf:TextField=new TextField();
    tf.selectable=false;
    tf.multiline=true;
    tf.width=120;
    tf.text="游戏结束~r得分:"+score+"r按空格键开始新游戏";
    addChild(tf);
}



function makeFood():Sprite//创建食物
{
    var food:Sprite=new Sprite();
    food.graphics.beginFill(0xff0000);
    food.graphics.drawRect(0,0,peace,peace);
    food.graphics.endFill();
    food.name = "food";
    return food;
}

function makeBody(color:uint=0x000000):Sprite//创建蛇身
{
    var body:Sprite=new Sprite();
    body.graphics.beginFill(color);
    body.graphics.drawRect(0,0,peace,peace);
    body.graphics.endFill();
    body.name = "body";
    return body;
}

function onTimer(e:TimerEvent):void
{
    for (var j:int=0; j<square.numChildren; j++)
    {
        var food:Sprite = square.getChildAt(j) as Sprite;
        if (food.name == "food")
        {
            for(var k:int=0;k<square.numChildren;k++)
            {
                var body:Sprite=square.getChildAt(k) as Sprite;
                if(body.name=="body")
                {
                    if (body.hitTestPoint(food.x+food.width/2,food.y+food.height/2))//如果吃到食物
                    {
                        foods--;//食物上限-1
                        score++;//分数+1
                        square.removeChild(food);//移除食物
                        var newbody = makeBody();
                        var lastBody:Sprite = snake[snake.length - 1] as Sprite;//在蛇尾位置创建蛇身
                        newbody.x = lastBody.x;
                        newbody.y = lastBody.y;
                        square.addChild(newbody);
                        snake.push(newbody);//将新的蛇身丢进蛇身数组
                    }
                }
            }
        }
    }
   
    for(j=1;j<snake.length-1;j++) //如果蛇头碰撞蛇身,游戏失败
    {
        body=snake[j] as Sprite;
        if(player.hitTestPoint(body.x+body.width/2,body.y+body.height/2))
        {
            gameOver();
            return;
        }
    }

    switch (direction)//判断键盘方向,进行移动
    {
        case "left" :
            player.x -=  peace;
            break;
        case "right" :
            player.x +=  peace;
            break;
        case "up" :
            player.y -=  peace;
            break;
        case "down" :
            player.y +=  peace;
            break;
    }
   
    if (playerPoint.length >= snake.length)playerPoint.splice(0,1);//节省内存,只保留蛇身相同长度的蛇头移动坐标记录
   
    if (player.x > bg.width-peace)//边界判断
    {
        player.x = 0;
    }else if (player.x<0)
    {
        player.x = bg.width-peace;
    }

    if (player.y > bg.height-peace)//边界判断
    {
        player.y = 0;
    }else if (player.y<0)
    {
        player.y = bg.height-peace;
    }
   
    playerPoint.push(new Point(player.x,player.y));//将蛇头新坐标放进蛇头坐标数组

    for (var i:int=1; i<=snake.length-1; i++)//蛇身跟着蛇头(延迟1步)移动
    {
        var loc:Point = playerPoint[playerPoint.length - i - 1] as Point;
        if (loc==null)return;
        snake[i].x = loc.x;
        snake[i].y = loc.y;
    }

}

function onSeed(e:TimerEvent):void//创建食物计时器
{
    if (foods < 3)//当场景上的食物总数小于3,才创建新的食物
    {
        var food = makeFood();
        food.x = Math.floor(Math.random() * 30) * peace;
        food.y = Math.floor(Math.random() * 30) * peace;
        square.addChild(food);
        foods++;
    }
}

function keyDown(e:KeyboardEvent):void//键盘按键监听
{
    switch (e.keyCode)
    {
        case 37 :
            direction=direction=="right"?"right":"left";
            break;
        case 38 :
            direction=direction=="down"?"down":"up";
            break;
        case 39 :
            direction=direction=="left"?"left":"right";
            break;
        case 40 :
            direction=direction=="up"?"up":"down";
            break;
        case 32:
            while(this.numChildren)
            {
                removeChild(this.getChildAt(0));
            }
            init();
            break;
    }
}

发表评论

电子邮件地址不会被公开。 必填项已用*标注

This site uses Akismet to reduce spam. Learn how your comment data is processed.